Tomcat x Oracle10g

Publicado por Perfil removido em 05/04/2006

[ Hits: 10.612 ]

 


Tomcat x Oracle10g



O TomCat utiliza a porta 8080 para servir páginas. O Oracle 10g utiliza a porta 8080 por padrão para servir dados através da interface XDB. O resultado disso: Fica com a porta quem chegar primeiro!

Se iniciarmos o TomCat e em seguida o Oracle, teremos uma tela de desafio requisitando usuário e senha para o utilitário XDB. Se iniciarmos o Oracle e em seguida o Tomcat, ele se apossa da porta 8080 e o uso do XDB fica "cancelado".

Para evitar conflitos entre o XDB do Oracle10g e o Tomcat, faça o seguinte:

1. Crie um arquivo no diretório "/home/oracle" chamado "xdb_utility.sql" contendo o seguinte:

CREATE OR REPLACE PACKAGE XDB_UTILITY as
 procedure SET_HTTP_PORT (PORT_NUMBER number);
 procedure SET_FTP_PORT (PORT_NUMBER number);
end XDB_UTILITY;
/
show errors
--
create or replace package body XDB_UTILITY as
--
FTP_XPATH varchar2(256) := '/xdbconfig/sysconfig/protocolconfig/ftpconfig/ftp-port';
HTTP_XPATH varchar2(256) := '/xdbconfig/sysconfig/protocolconfig/httpconfig/http-port';
--
procedure SET_XDB_PORT(PORT_XPATH varchar2, PORT_NUMBER number) as
   config XMLType;
begin
   config := dbms_xdb.cfg_get();
   select updateXML(config, PORT_XPATH, PORT_NUMBER)
   into config
   from dual;
   dbms_xdb.cfg_update(config);
   commit;
   dbms_xdb.cfg_refresh();
end;
----
-- ROTINAS PARA ALTERAR PORTAS
--
procedure SET_HTTP_PORT(PORT_NUMBER number) as
begin
  SET_XDB_PORT(HTTP_XPATH || '/text()', PORT_NUMBER);
end;
--
procedure SET_FTP_PORT(PORT_NUMBER number) as
begin
  SET_XDB_PORT(FTP_XPATH || '/text()', PORT_NUMBER);
end;
--
end XDB_UTILITY;
/
show errors
--
create or replace public synonym XDB_UTILITY for XDB_UTILITY
/
grant execute on XDB_UTILITY to XDBADMIN
/

2. Ainda no diretório "/home/oracle", conecte no banco como "SYSDBA";

3. Compile o código com o comando:

# sqlplus> @xdb_utility.sql

4. Chame a função:

# sqlplus> call xdb_utility.set_http_port(n);

Onde "n" é a nova porta que o XDB deverá utilizar para servir dados. 8081, por exemplo.

Obs.: Nesse script você também pode alterar a porta de FTP utilizada pelo XDB chamando:

# sqlplus> call xdb_utility.set_ftp_pot(n);

5. Para testar, acesse o XDB do Oracle 10g em sua nova porta: http://localhost:8081. Note agora a tela de desafio:


Não é necessário reiniciar nada. No próximo acesso ao servidor - http://servidor:8080 - a página do TomCat Manager deverá ser exibida.

E é só. Espero que seja uma dica útil.

Fonte: Oracle Metalink

Outras dicas deste autor

Gmanedit - Editando, criando e contribuindo com documentação

elementaryOS Beta 2 - Instalação com instalador atualizado

Sorria... você está sendo filmado! Versão: ZoneMinder

Ativando o NUMLOCK na tty1 quando ligar o PC automaticamente

Rodando DVDs encriptados no Ubuntu Linux

Leitura recomendada

Oracle 11g - erro: An unexpected error has been detected by HotSpot Virtual Machine

Descobrir se uma determinada tabela, sinonimo ou usuário existe no Oracle

Instalando Oracle 10g xE no Ubuntu

Instalação e Configuração do Oracle Express Edition e SQL Developer no Ubuntu

Oracle - Criar usuário com privilégio de DBA

  

Comentários

Nenhum comentário foi encontrado.



Contribuir com comentário




Patrocínio

Site hospedado pelo provedor RedeHost.
Linux banner

Destaques

Artigos

Dicas

Tópicos

Top 10 do mês

Scripts